**Programa e Bloco**

<programa> ::=   
**program** <*identificador*> **;** <bloco>**.**

<bloco> ::=  
<parte de declarações de variáveis> <parte de declarações de procedimentos> <comando composto>

**Declarações**

<parte de declarações de variáveis> ::=  
{ **var** <declaração de variáveis> {**;** <declaração de variáveis>} **;** }

<declaração de variáveis> ::=  
<lista de identificadores> **:** <tipo>

<lista de identificadores> ::=   
<*identificador*> { **,** <*identificador*> }

<tipo> ::=   
**integer** | **real** | **boolean**

<parte de declarações de procedimentos> ::=  
{ <declaração de procedimento> **;** }

<declaração de procedimento> ::=  
{ **procedure** <*identificador*> [<parâmetros formais>] **;** <bloco> }

<parâmetros formais> ::=  
( <seção de parâmetros formais> { **;** <seção de parâmetros formais>} )

<seção de parâmetros formais> ::=  
{ **var** } <lista de identificadores> **:** <tipo>

**Comandos**

<comando composto> ::=   
**begin** <comando> { **;** <comando> } **end**

<comado> ::=  
<atribuição> | <chamada de procedimento> | <comando composto> | <comando condicional 1>  
| <comando repetitivo 1>

<atribuição> ::=   
<variável> **:=** <expressão>

<chamada de procedimento> ::=  
<*identificador*> [ **(** <lista de expressões> **)** ]

<comando condicional 1> ::=  
**if** <expressão> **then** <comando> [ **else** <comando> ]

<comando repetitivo 1> ::=  
**while** <expressão> **do** <comando>

**Expressões**

<expressão> ::=  
<expressão simples> [ <relação> <expressão simples> ]

<relação> ::=   
**=** | <**>** | < | <= | >= | >

<expressão simples> ::=  
[ **+** | **-** ] <termo> { ( **+** | **-** | **or** ) <termo> }

<termo> ::=  
<fator> { ( **\*** | **/** | **div** | **and** ) <fator> }

<fator> ::=  
<variável> | <*número*> | ( <expressão> ) | **not** <fator>

<variável> ::=   
<*identificador*>

<lista de expressões> ::=   
<expressão> { **,** <expressão> }